Variationen mit Zurücklegen

Eingestellt: 02.02.2009
Letzte Änderung: 20.12.2010


Keywords: Kombinatorik • Variationen • Zurücklegen • Reihenfolge
Betrifft: Excel-Formel für die Anzahl der Variationen mit Zurücklegen und deren Auflistung
Verwandte Themen:
Variationen ohne Zurücklegen
Kombinationen mit ZurücklegenKombinationen ohne Zurücklegen
Binomialkoeffizient • Multinomialkoeffizient
Binomische Formeln • Multinomische Formel • Permutationen


 

Definitionen

Gegeben seien unterscheidbare Objekte, aus denen Objekte ausgewählt werden. Zu unterscheiden ist, ob mit oder ohne Zurücklegen ausgewählt wird, und ob die Reihenfolge, in der die Objekte ausgewählt werden, berücksichtigt wird oder nicht. Dabei wird eine Auswahl mit Berücksichtigung der Reihenfolge als Variation, eine Auswahl ohne Berücksichtigung der Reihenfolge als Kombination bezeichnet.

Kombinationen ohne Zurücklegen Variationen ohne Zurücklegen
Kombinationen mit Zurücklegen Variationen mit Zurücklegen

 

Variationen mit Zurücklegen

Beim Ziehen mit Zurücklegen unter Berücksichtigung der Reihenfolge gibt es

verschiedene Möglichkeiten.

 

Excel-Formel für die Anzahl der Variationen mit Zurücklegen

Zur Ermittlung der Anzahl der Variationen mit Zurücklegen existiert keine Excel-Funktion, so dass auf eine Excel-Formel zurückgegriffen wird. Hierzu sei zunächst folgendes Beispiel 01 betrachtet.

Beispiel 01: Lampen
In einem Raum gibt es 4 Lampen, die unabhängig voneinander ein- und ausgeschaltet werden können. Wie viele Möglichkeiten der Beleuchtung (keine Beleuchtung mit eingeschlossen) gibt es?


Beispiel 01: Lampen

Formel in der Tabelle:
D2: =B1^B2

 

Excel-Formel für die Auflistung der Variationen mit Zurücklegen

Neben der Anzahl der Variationen mit Zurücklegen interessiert häufig auch eine Auflistung dieser. Eine solche kann zur Illustration des Sachverhalts oder als Grundlage weiterer Überlegungen und Berechnungen nützlich sein. Unter Verwendung von Beispiel 01 können folgende dynamische Excel-Formeln verwendet werden, wobei die Zellen B1:B2 als Eingabebereich dienen:


Arbeitstabelle 01: Lampen

Formeln in der Tabelle:
D2: =B1^B2
A5: =WENN($B$1^$B$2<ZEILE(A1);"";ZEILE(A1))
Formel nach unten kopieren
B4: =WENN(SPALTE(A:A)>$B$2;"";SPALTE(A:A))
Formeln nach rechts kopieren
B5: =WENN(ODER(B$4>$B$2;$B$1^$B$2<$A5);"";
REST(GANZZAHL(($A5-1)/$B$1^($B$2-B$4));$B$1))
bzw.
B5: =WENN(ODER(SPALTE(A:A)>$B$2;$B$1^$B$2<ZEILE(A1));"";
REST(GANZZAHL((ZEILE(A1)-1)/$B$1^($B$2-SPALTE(A:A)));$B$1))
Formel nach unten und nach rechts kopieren

In Spalte A steht der Index für die -te Variation mit Zurücklegen , in den folgenden Spalten der Zeile 4 das -te Objekt . Die obere der beiden angegebenen Excel-Formeln in Zelle B5 greift auf diese Indizes zurück, während die untere unabhängig von diesen ist. Die Excel-Formeln sind in dieser Form insbesondere durch die maximalen Spalten- und Zeilenanzahl in Excel begrenzt.

 

Weitere Beispiele und Anwendungsbereiche

Beispiel 02: Zahlenschloss
Wieviele Möglichkeiten gibt es bei einem Zahlenschloss mit drei Ringen, wobei an jedem Ring 10 Ziffern (0, 1, 2, 3, 4, 5, 6, 7, 8, 9) eingestellt werden können?


Arbeitstabelle 02: Zahlenschloss (Ausschnitt)

 

Beispiel 03: TOTO-Tipp
Wie viele Möglichkeiten gibt es bei einem TOTO-Tipp mit 13 Spielen? Bei dieser Ergebniswette wird der Spielausgang von 13 Fußballspielen vorhergesagt, wobei sich die Gewinnzahlen aus den Ziffern 0 bei einem Unentschieden, 1 bei einem Heimsieg und 2 bei einem Sieg der Gastmannschaft der jeweiligen Spiele ergeben.


Arbeitstabelle 03: TOTO-Tipp (Ausschnitt)

Um alle Variationen aufzuführen, empfiehlt es sich auf ein Makro auszuweichen, welches diesem oder einem ähnlichen Algorithmus folgt und alle Ziffern einer Variation in eine Zelle schreibt. Bei dieser Vorgehensweise werden 24 Spalten à 65.536 Zeilen und 21.259 Zeilen in einer weiteren Spalte belegt.

 

Beispiel 04: Frage des 'Fürsten der Toskana' an Galileo Galilei
Warum erscheint beim Wurf dreier (unterscheidbarer) Laplace-Würfel die Summe 10 öfter als die Summe 9, obwohl beide Summen auf 6 Arten eintreten können? Berechnen Sie die beiden zugehörigen Wahrscheinlichkeiten.


Arbeitstabelle 04: Frage des 'Fürsten der Toskana' an Galileo Galilei (Ausschnitt)

Formeln in der Tabelle:
D2: =B1^B2
A5: =WENN($B$1^$B$2<ZEILE(A1);"";ZEILE(A1))
Formel nach unten bis einschließlich Zeile 220 kopieren
B4: =WENN(SPALTE(A:A)>$B$2;"";SPALTE(A:A))
Formel nach rechts bis einschließlich Spalte D kopieren
B5: =WENN(ODER(B$4>$B$2;$B$1^$B$2<$A5);"";
REST(GANZZAHL(($A5-1)/$B$1^($B$2-B$4));$B$1)+1)
Formel nach unten und nach rechts kopieren
E5: =SUMME(B5:D5)
Formel nach unten bis einschließlich Zeile 220 kopieren
G1: =ZÄHLENWENN($E$5:$E$220;F1)
H1: =ZÄHLENWENN($E$5:$E$220;F2)

Die Anzahl der Variationen mit Zurücklegen und die Indizes ergeben sich analog zu obigen Beispielen. Innerhalb der Matrix stehen alle zugehörigen Variationen,  wobei hier jedoch die Excel-Formel in Zelle B5 mit +1 transformiert ist. In Spalte E wird die Summe der Augenzahlen einer jeden Variation gebildet. Die Excel-Funktion ZÄHLENWENN bestimmt in Zelle G1 (bzw. G2) die Anzahl der Variationen, bei der die Summe der Augen der drei Würfel 10 (bzw. 9) beträgt. Offensichtlich liegen 27 (bzw. 25) Variationen vor. Die Wahrscheinlichkeiten bestimmen sich demnach (auf fünf Stellen nach dem Komma gerundet) wie folgt:

Über die Auflistung aller Variationen mit Zurücklegen und der Excel-Funktion ZÄHLENWENN wird die Anzahl der verschiedenen Anordnungen bestimmt, die sich aus den 6 Zerlegungen der Zahl 10 (bzw. 9) ergeben. Die Anordnungen können in Arbeitstabelle 04 angezeigt werden, indem in Zeile 4 ein Autofilter gesetzt und die Spalte E nach der Zahl 10 (bzw. 9) gefiltert wird.

 

Beispiel 05: Zahlensysteme
Ein genauerer Blick auf die obigen Beispiele zeigt, dass diese Excel-Formel ebenfalls eine Umwandlung von Zahlen vom Dezimalsystem in andere Zahlensysteme erlaubt (Beispiel 01: Binär- bzw. Dualsystem, Beispiel 03: Tertiär- bzw. 3er-System). Eine weiterführende Diskussion zu diesem Thema finden Sie im Artikel Umrechnung von Zahlensystemen.

 

Haben Sie Fragen oder Anregungen zu diesem Artikel?

Dann senden Sie einfach eine Nachricht an:

E-Mail:

 

Lesen Sie auch:
___________________________________________________________________

Variationen ohne Zurücklegen