Rosenbluth-Index (Rosenbluth index)

Eingestellt: 23.12.2007
Letzte Änderung: 23.12.2007


Keywords: Konzentrationsmessung • Konzentrationsrate • Konzentrationskurve • Rosenbluth-Index • Herfindahl-Index
Betrifft:  Excel-Formeln für den Rosenbluth-Index
Verwandte Themen: 
Disparitätsmaße • Gini-KoeffizientGinis mittlere Differenz • Lorenzkurve • normierter Gini-KoeffizientVariationskoeffizient • Ungleichheitsmaße


 

Definition

Der Rosenbluth-Index  ist ein Konzentrationsmaß und ist definiert als eins durch zweimal der Fläche , die innerhalb des Rechtecks  und oberhalb der Konzentrationskurve liegt, und kann als ein mit dem Index gewichtetes Mittel der absteigend geordneten Merkmalswerte  geschrieben werden:

Offenbar liegt maximale Konzentration vor, wenn

und minimale Konzentration bei festen , wenn

ist.

 

Beispiel

In einem kleinen Unternehmen liegen folgende 10 Managergehälter vor, für die Sie den Rosenbluth-Index bestimmen sollen:


Beispiel Managergehälter

Da Excel keine Excel-Funktion für den Rosenbluth-Index bereitstellt, soll zunächst mit Hilfe der nachstehenden Arbeitstabelle eine Berechnung des Gini-Koeffizienten erfolgen. Für den Bereich A2:A11 ist der Name x definiert.


Arbeitstabelle Rosenbluth-Index

Formeln in der Tabelle:
C2: =Zeile(A1)
D2: =KGRÖSSTE(x;ZEILE(A1))
E2: =D2/SUMME(x)
F2: =C2*E2
Formeln jeweils nach unten kopieren bis einschließlich Zeile 11
D12: =SUMME(D2:D11)
E12: =SUMME(E2:E11)
F12: =SUMME(F2:F11)

Der Index  in Spalte C kann mittels der Excel-Funktion ZEILE, die absteigend sortierten Managergehälter  in Spalte D mittels der Excel-Funktion KGRÖSSTE ermittelt werden. In Spalte E finden sich die Merkmalsanteile und in Spalte F das Produkt aus Indexwert und entsprechenden Merkmalsanteil . Der Rosenbluth-Index ergibt sich aus

=1/(2*F12-1)

und beträgt für dieses Beispiel 0,12625644.

 

Excel-Formeln für den Rosenbluth-Index

Um nicht für jede Berechnung auf eine Arbeitstabelle zurück zu greifen, kann der Rosenbluth-Index wie folgt bestimmt werden.

{=1/(2*SUMME(ZEILE(INDIREKT("1:"&ANZAHL(x)))* 
KGRÖSSTE(x;ZEILE(INDIREKT("1:"&ANZAHL(x)))))/SUMME(x)-1)}

wobei die Formel als Arrayformel einzugeben und x der definierte Name für den Bereich A2:A11 ist.

Ferner besteht zwischen dem Rosenbluth-Index  und dem Gini-Koeffizienten   folgende Beziehung:

so dass eine hierzu korrespondierende Excel-Formel für den Rosendahl-Index lautet:

=1/(ANZAHL(x)*(1-DG))

wobei für den Gini-Koeffizienten der Name DG definiert ist und welcher für dieses Beispiel 0,20796117 beträgt.

Wird noch die Beziehung des Gini-Koeffizienten zu Ginis mittlere Differenz  ausgenutzt, dann lässt sich für den Rosenbluth-Index schreiben:

Nach Umformung des Nenners lässt sich schließlich eine kürzere Schreibweise für eine Excel-Formel für den Rosenbluth-Index  finden:

{=1/(ANZAHL(x)-SUMME(ABS(x-MTRANS(x)))/(2*SUMME(x)))}

wobei die Formel als Arrayformel einzugeben und x der definierte Name für den Bereich A2:A11 ist.

 

Haben Sie Fragen oder Anregungen zu diesem Artikel?

Dann senden Sie einfach eine Nachricht an:

E-Mail:

 

Lesen Sie auch:
___________________________________________________________________

Excel-Formel für den Gini-Koeffizienten