Schnittpunkte zweier normalverteilter Dichtefunktionen

Eingestellt: 28.04.2008
Letzte Änderung: 28.04.2008


 

Einleitung

Gegeben sind zwei normalverteilte (Gauß-verteilte) Zufallsvariablen 

und den Dichtefunktionen (Gaußsche Glockenkurve):

Gleichsetzen

und umformen ergibt die quadratische Gleichung


Gilt , dann können die Schnittpunkte durch Anwendung der p/q-Formel:

mit

und

ermittelt werden.

Ferner vereinfacht sich obige Gleichung im Spezialfall  zu

Demgegenüber ist die p/q-Formel für nicht (wohl-)definiert.

Im Spezialfall lässt sich jedoch aus einem der Zwischenschritte zu obigen Umformungen zeigen, dass ein Schnittpunkt bei

 

vorliegt.

Nehmen darüberhinaus auch die Erwartungswerte gleiche Werte an, so fallen die Dichtefunktionen zusammen.

 

Herleitung einer Excel-Funktion

Zur Bestimmung der Schnittpunkte zweier normalverteilter Dichtefunktionen in Excel sei folgendes Beispiel 01 betrachtet, wobei μi den Erwartungswert und σi die Standardabweichung der normalverteilten Zufallsvariable Yi (i=1,2) angibt.


Beispiel 01: Werte der Parameter der beiden Normalverteilungen

Es werden die Namen p und q definiert:

p: =(2*($C$2*$B$3^2-$B$2*$C$3^2))/($C$3^2-$B$3^2)
q: =($B$2^2*$C$3^2-$C$2^2*$B$3^2-2*LN($C$3/$B$3)*$B$3^2*$C$3^2) / ($C$3^2-$B$3^2)

sowie für den Fall gleicher Standardabweichungen und unterschiedlicher Erwartungswerte:

x_1: =($B$2+$C$2)/2

Die Schnittpunkte berechnen sich wie folgt:


Arbeitstabelle 01: Berechnung der Schnittpunkte

Formeln in der Tabelle:
B6: =WENN(UND(B2=C2;B3=C3);NV();WENN(B3=C3;x_1;-p/2-((p/2)^2-q)^0,5))
C6: =WENN(B3=C3;NV();-p/2+((p/2)^2-q)^0,5)
B7: =NORMVERT(B6;B$2;B$3;0)
C7: =NORMVERT(C6;C$2;C$3;0)

Mit Hilfe der definierten Namen p, q und x_1 lassen sich die Excel-Formeln sehr stark verkürzen und somit übersichtlich darstellen. Die Formeln in den Zellen B6 und C6 sind mit der Excel-Funktion NV() daraufhin angepasst, dass die berechneten Werte je nach Fall in einem Diagramm dar- bzw. nicht dargestellt werden.

Entsprechen sich sowohl die Standardabweichungen als auch die Erwartungswerte beider Normalverteilungen, so wird dies durch die erste WENN-Funktion in Zelle B6 abgefangen. Die Ausgabe des Fehlerwertes #NV in B6 unterdrückt eine Darstellung eines Wertes bzw. Schnittpunkts im Diagramm.

Die zweite WENN-Funktion in Zelle B6 greift, wenn identische Standardabweichungen und unterschiedliche Erwartungswerte vorliegen. In diesem Fall liegt ein Schnittpunkt vor, welcher in B6:B7 angezeigt wird. In C6 dagegen genügt somit eine WENN-Funktion, welche einen Fehlerwert #NV liefert, wenn die Standardabweichungen gleich sind.

Liegen für die Standardabweichungen unterschiedliche Werte vor, wird die p/q-Formel angewendet. Es wird immer der kleinere x-Wert der Schnittpunkte in B6 und der größere in C6 ausgewiesen.

Die berechneten Schnittpunkte können mit den zugehörigen Dichtefunktionen in einem Punkt(XY)-Diagramm schematisch dargestellt werden:


Diagramm 01: Schnittpunkte zweier normalverteilter Dichtefunktionen

Wie gezeigt ist die hergeleitete Excel-Formel für alle Fälle definiert. Nachstehend wird jedoch noch kurz auf die drei genannten Spezialfälle eingegangen.

 

Spezialfall I: 

Sind die Erwartungswerte der beiden Normalverteilungen null, so existieren bei unterschiedlichen Standardabweichungen weiterhin 2 Schnittpunkte.


Beispiel 02: Werte der Parameter der beiden Normalverteilungen

Die Berechnung kann nun mittels der vereinfachten Gleichung erfolgen:


Arbeitstabelle 02: Berechnung der Schnittpunkte

Formeln in der Tabelle:
B6: =-C6
C6: =((2*LN(C3/B3)*B3^2*C3^2)/(C3^2-B3^2))^0,5
B7: =NORMVERT(B6;B$2;B$3;0)
C7: =NORMVERT(C6;C$2;C$3;0)

Eine Darstellung der Schnittpunkte im Punkt(XY)-Diagramm kann wie folgt aussehen:


Diagramm 02: Schnittpunkte zweier normalverteilter Dichtefunktionen

 

Spezialfall II: 

Im Fall identischer Standardabweichungen und unterschiedlicher Erwartungswerte liegt lediglich ein Schnittpunkt vor.


Beispiel 03: Werte der Parameter der beiden Normalverteilungen

Der Schnittpunkt lässt sich berechnen mit:


Arbeitstabelle 03: Berechnung des Schnittpunkts

Formeln in der Tabelle:
B6: =($B$2+$C$2)/2
bzw.
B6: =x_1
B7: =NORMVERT(B6;B$2;B$3;0)

Eine mögliche Darstellungsform des Schnittpunkts im Punkt(XY)-Diagramm ist:


Diagramm 03: Schnittpunkt zweier normalverteilter Dichtefunktionen

 

Spezialfall III: 

Nehmen die Parameter beider Verteilungen identische Werte an, so fallen ihre Dichtefunktionen zusammen.


Beispiel 04: Werte der Parameter der beiden Normalverteilungen


Diagramm 04: Normalverteilte Dichtefunktionen mit identischen Parametern

 

Haben Sie Fragen oder Anregungen zu diesem Artikel?

Dann senden Sie einfach eine Nachricht an:

E-Mail:

 

Lesen Sie auch:
___________________________________________________________________

Excel-Formel für den Gini-Koeffizient