Gini-Koeffizient (Gini coefficient)

Eingestellt: 20.12.2007
Letzte Änderung: 20.12.2007


Keywords: Disparitätsmaße • Gini-Koeffizient • Ginis mittlere Differenz • Lorenz- kurve • normierter Gini-Koeffizient • Variationskoeffizient • Ungleichheitsmaße
Betrifft:  Excel-Formeln für den Gini-Koeffizient, normierten Gini-Koeffizient und Variationskoeffizienten
Verwandte Themen: Konzentrationsmessung • Konzentrationsrate • Konzentra- tionskurve • Rosenbluth-IndexHerfindahl-Index


 

Definition

Der Gini-Koeffizient ist ein Disparitätsmaß und ist definiert als zweimal die Fläche zwischen der Lorenzkurve und der Diagonalen im Einheitsquadrat und kann als ein gewichtetes Mittel der aufsteigend geordneten Merkmalswerte geschrieben werden

Offenbar liegt minimale Disparität vor, wenn

und maximale Disparität, wenn

ist.

 

Beispiel

In einem kleinen Unternehmen liegen folgende 10 Managergehälter vor, für die Sie den Gini-Koeffizienten bestimmen sollen:


Beispiel Managergehälter

Da Excel keine Excel-Funktion für den Gini-Koeffizienten bereitstellt, soll zunächst mit Hilfe der nachstehenden Arbeitstabelle eine Berechnung des Gini-Koeffizienten erfolgen. Für den Bereich A2:A11 ist der Name x definiert.


Arbeitstabelle Gini-Koeffizient

Formeln in der Tabelle:
C2: =Zeile(A1)
D2: =KKLEINSTE(x;ZEILE(A1))
E2: =D2/SUMME(x)
F2: =(2*C2-ANZAHL(x)-1)/ANZAHL(x)
G2: =E2*F2
Formeln jeweils nach unten kopieren bis einschließlich Zeile 11
D12: =SUMME(D2:D11)
E12: =SUMME(E2:E11)
F12: =SUMME(F2:F11)
G12: =SUMME(G2:G11)

Der Index  in Spalte C kann mittels der Excel-Funktion ZEILE, die aufsteigend sortierten Managergehälter  in Spalte D mittels der Excel-Funktion KKLEINSTE ermittelt werden. In Spalte E finden sich die Merkmalsanteile  und in Spalte F die Gewichte . Zu beachten ist, dass die Gewichte teilweise negativ und teilweise positiv sind und deren Summe null beträgt. In Spalte G erfolgt jeweils eine Multiplikation des i-ten Merkmalsanteils mit dem i-ten Gewicht. Die Summe dieser Multiplikationen ergibt den Gini-Koeffizienten, welcher für dieses Beispiel 0,20796117 beträgt.

 

Excel-Formeln für den Gini-Koeffizienten

Um nicht für jede Berechnung auf eine Arbeitstabelle zurück zu greifen, kann der Gini-Koeffizient wie folgt bestimmt werden.

Unter Berücksichtigung eines Zeilenindexes (Spalte C) und aufsteigend sortierter Daten (Spalte D):
=SUMMENPRODUKT(((2*(C2:C11)-ANZAHL(C2:C11)-1)/ANZAHL(C2:C11)); (D2:D11/SUMME(D2:D11)))

Unter Berücksichtigung aufsteigend sortierter Daten (Spalte D) ohne Zeilenindex:
=SUMMENPRODUKT(((2*(ZEILE(1:10))-ANZAHL(D2:D11)-1)/ANZAHL(D2:D11)); (KKLEINSTE(D2:D11;ZEILE(1:10))/SUMME(D2:D11)))

Eine kürzere Schreibweise, welche weder aufsteigend sortierte Daten noch einen Zeilenindex verlangt, lässt sich aus der Beziehung des Gini-Koeffizienten zu Ginis mittlere Differenz ableiten:



Der Gini-Koeffizient entspricht der Hälfte von Ginis mittlere Differenz geteilt durch das arithmetische Mittel. Eine korrespondierende Excel-Formel lautet:
{=SUMME(ABS(x-MTRANS(x)))/(2*MITTELWERT(x)*ANZAHL(x)^2)}.
Bei dieser Excel-Formel kann im Zähler ein n eliminiert werden, so dass eine noch kürzere Schreibweise für den Gini-Koeffizienten möglich ist:

{=SUMME(ABS(x-MTRANS(x)))/(2*SUMME(x)*ANZAHL(x))}

wobei die Formeln jeweils als Arrayformel einzugeben sind und x der definierte Name für den Bereich A2:A11 ist.

 

Darüber hinaus besteht zwischen den Gini-Koeffizienten  und dem Rosenbluth-Index folgende Beziehung:

so dass eine hierzu korrespondierende Excel-Formel für den Gini-Koeffizienten lautet:

=1-(1/(ANZAHL(x)*KR))

wobei für den Rosenbluth-Index der Name KR definiert ist. Der Rosenbluth-Index beträgt für dieses Beispiel 0,12625644.

Schließlich ergibt sich der normierte Gini-Koeffizient  aus



und kann als Arrayformel geschrieben werden mit:

{=SUMME(ABS(x-MTRANS(x)))/(2*SUMME(x)*(ANZAHL(x)-1))}

Der normierte Gini-Koeffizient  beträgt für dieses Beispiel 0,23106796.

 

Haben Sie Fragen oder Anregungen zu diesem Artikel?

Dann senden Sie einfach eine Nachricht an:

E-Mail:

 

Lesen Sie auch:
___________________________________________________________________

Excel-Formel für den Rosenbluth-Index