Was ist eine Arrayformel (Matrixformel)?

Eingestellt: 03.11.2007
Letzte Änderung: 03.11.2007


 

Kurzbeschreibung

Arrayformeln - auch als Matrixformeln bekannt - sind Formeln, die mehrere Rechenoperationen durchführen und sich auf zusammenhängende, nicht zusammenhängende Bereiche und / oder Arraykonstanten beziehen.[1] Darüber hinaus können in einer solchen Formel mehrere Excel-Funktionen  und / oder Texte mit eingebunden sein. Als Resultat liefert eine Arrayformel ein einzelnes Ergebnis oder mehrere Ergebnisse, wobei dieses im letzteren Fall ein Zeilenvektor, ein Spaltenvektor oder eine mehrdimensionale Matrix sein kann.

 

Kennzeichen einer Arrayformel

Eine Arrayformel zeichnet sich dadurch aus, dass deren Eingabe nicht wie üblich mit der Eingabetaste, sondern mit der Tastenkombination Strg+UMSCHALT+Eingabe (bzw. Ctrl+Shift+Return) abgeschlossen wird. Eine so eingegebene Formel wird in der Bearbeitungsleiste in {geschweiften Klammern} dargestellt. Für bestimmte Excel-Funktionen ist eine Eingabe als Arrayformel erforderlich.

Abbildung: Tastenkombination Strg+UMSCHALT+Eingabe für eine Arrayformel.

Folgendes einfaches Beispiel 01 illustriert den Sachverhalt. Es liegen 5 Messwerte vor, deren Summe der Absolutbeträge ermittelt werden soll.


Formeln in der Tabelle:
C2: =ABS(B2)
Formel nach unten kopieren bis Zelle C6
C7: =SUMME(C2:C6)
C9: {=SUMME(ABS(B2:B6))}

Beispiel 01: Arrayformel mit einer einzelnen Ergebniszelle.

Im Bereich B2:B6 stehen die 5 Messwerte, in der Hilfsspalte C werden die zugehörigen Absolutbeträge mit der Excel-Funktion ABS berechnet. Die Summe der Absolutbeträge ergibt sich in Zelle C7 mittels der Excel-Funktion SUMME. Die beiden Rechenschritte lassen sich anhand einer Arrayformel bestehend aus den beiden Excel-Funktionen SUMME und ABS wie in Zelle C9 ausdrücken. Ersichtlich ist, dass der erste Rechenschritt, also die Berechnung der Absolutbeträge, im inneren Teil der Arrayformel steht, der zweite Schritt, also die Ermittlung der Summe der Absolutbeträge, sich im äußeren Teil der Arrayformel befindet. Das Resultat dieser Arrayformel wird in einer Zelle zurückgegeben.

Demgegenüber führt eine Berechnung der Absolutbeträge mit Hilfe einer Arrayformel zu mehreren (hier: 5) Ergebnissen in Form eines Spaltenvektors. Dazu werden die Zellen C2:C6 markiert, in der Bearbeitungsleiste =ABS(B2:B6) eingegeben und die Formel mit Strg+UMSCHALT+Eingabe (bzw. Ctrl+Shift+Return) abgeschlossen.

Beispiel 01: Arrayformel mit mehreren Ergebnissen vor Abschluss der Formel.

Beispiel 01: Arrayformel mit mehreren Ergebnissen nach Abschluss der Formel.

Alternativ zur Eingabe in der Bearbeitungszeile kann nach dem Markieren auch mit Drücken der Funktionstaste F2 die Arrayformel in der zuerst markierten Zelle eingegeben werden.

 

Fehlermeldungen und Fehlerbehebung bei Arrayformeln

Wie bei jeder Excel-Funktion und Excel-Formel kann es auch bei Arrayformeln zu Fehlermeldungen kommen. Die wichtigsten Fehlermeldungen seien hier diskutiert.

• Fehlertyp #WERT!

Eine der häufigsten Fehlermeldungen bei der Verwendung von Arrayformeln ist der Fehlertyp #WERT!. Hauptursache dieses Fehlers ist, dass die Arrayformel mit der Eingabetaste und nicht wie gefordert mit Strg+UMSCHALT+Eingabe (bzw. Ctrl+Shift+Return) abgeschlossen wurde wie bspw. bei der Formel =SUMME(ABS(B2:B6)) aus Beispiel 01. Markieren Sie die Zelle oder den Zellbereich der Arrayformel, drücken Sie die Funktionstaste F2 und schließen Sie die Formel mit Strg+UMSCHALT+Eingabe (bzw. Ctrl+Shift+Return) ab.[2]

Ferner kann das Ergebnis #WERT! lauten, wenn die Zellen Texte enthalten oder leer sind, aber Zahlen erfordern. Wird anstelle der Messwerte in Beispiel 01  Text eingegeben (Zellbereich: B2:B6), so liefern die Arrayformeln die Fehlermeldung #WERT!.

Eine weitere Ursache der Fehlermeldung #WERT! ist, dass die Dimension des Arrays ungültig ist, d.h. die Anzahl von Zeilen und Spalten, die als Bezug und / oder Ergebnis dienen, sind falsch gewählt worden. So erfordert die Excel-Matrixfunktion MINV, welche als Arrayformel eingegeben werden muss, eine quadratische Matrix. Entspricht in dieser Ausgangsmatrix die Anzahl der Spalten nicht der Anzahl der Zeilen, so erscheint für alle Zellen eine solche Fehlermeldung (unabhängig der Dimension der Ergebnismatrix) als Ergebnis wie Beispiel 02 zeigt.


Formeln in der Tabelle:
A5:B6: {=MINV(A1:C2)}
A8:B9: {=MINV(A1:B2)}

Beispiel 02: Excel-Funktion MINV mit ungültiger und gültiger Ausgangsmatrix.

• Fehlertyp #NV

Ferner kann eine ungültige Dimension des Arrays zu der Fehlermeldung #NV führen und betrifft sowohl die Ausgangs- als auch Ergebnismatrizen. Ein Fehlertyp #NV kann bei falscher Wahl der Ausgangsmatrix bspw. dann auftreten, wenn diese ungleich groß und durch Rechenoperatoren miteinander verknüpft sind. Möchten Sie etwa die Produktsumme aus den Messwerte und den zugehörigen Absolutbeträgen in Beispiel 01 berechnen und wählen die Ausgangsmatrizen wie in Zelle B10, dann wird die Fehlermeldung #NV zurückgegeben, da die Anzahl der Zeilen der beiden Spaltenvektoren nicht übereinstimmt und so die Rechenoperation zu einem Fehler führt. Eine korrekte Schreibweise dieser Berechnung findet sich in Zelle C10.


Formeln in der Tabelle:
B10: {=SUMME(B2:B7*C2:C6)}
C10: {=SUMME(B2:B6*C2:C6)}

Beispiel 01: Arrayformel mit ungültiger und gültiger Ausgangsmatrix.

Bei Wahl einer zu klein dimensionierten Ergebnismatrix werden lediglich die oberen linken Ergebnisse entsprechend der Anzahl der markierten Zellen ausgegeben. Ist dagegen die Ergebnismatrix zu groß dimensioniert, so können die Zellen des zu groß markierten Bereichs die Fehlermeldung #NV zurückliefern. Betrachtet sei hierzu eine Arrayformel mit mehrdimensionaler Ergebnismatrix. Bspw. sollen die Messwerte und Absolutbeträge aus Beispiel 01 ( Zellen B2:C6) mit der Zahl 3 potenziert werden. Aufgrund der 5x2-Ausgangsmatrix und den durchzuführenden Rechenoperationen ergibt sich wiederum eine 5x2-Ergebnismatrix. Wird jedoch ein zu großer Bereich (Zellen A12:C17, also eine 6x3-Matrix) markiert und die Arrayformel für diese eingegeben, so zeigt sich, dass die über die 5x2-Matrix hinausgehenden Zellen mit dem Fehlerwert #NV belegt sind.


Formeln in der Tabelle:
A12:C17: {=B2:C6^3}

Beispiel 01: Arrayformel mit zu groß dimensionierter Ergebnismatrix - 1 -

Liefert die Arrayformel ein einzelnes Ergebnis und die Ergebnismatrix ist zu groß gewählt, so wird dieses Ergebnis in allen Zellen dieser Ergebnismatrix zurückgegeben. Bei einem Zeilenvektor (bzw. Spaltenvektor) und zu groß dimensionierter Ergebnismatrix werden die Ergebnisse in den weiteren Zeilen (bzw. Spalten) wiederholt ausgegeben und in den zusätzlichen Spalten (bzw. Zeilen) erscheint die Fehlermeldung #NV. So ergibt sich mit Beispiel 01 eine Addition des i-ten Messwertes mit dem zugehörigen Absolutbetrag bei 5 Messwerten eine 5x1 Matrix (Spaltenvektor). Wird ein größerer Bereich als Ergebnismatrix gewählt (bspw. E1:F6), so werden die Ergebnisse in den zusätzlichen Spalten wiederholt, in den zusätzlichen Zeilen als Fehlerwert zurückgegeben. Umgekehrt stellt sich der Sachverhalt da, wenn eine Arrayformel zugrundeliegt, die als Ergebnis einen Zeilenvektor liefert (bspw. H1:J3).


Formeln in der Tabelle:
E1:F6: {=B2:B6+C2:C6}
H1:J3: {=B2:C2+B3:C3}

Beispiel 01: Arrayformel mit zu groß dimensionierter Ergebnismatrix - 2 -

• Bearbeitung einer Arrayformel

Möchten Sie aus Zelle C2 die Arrayformel des Beispiels 01 löschen, so erscheint der Hinweis, dass Teile eines Array nicht geändert werden können.

Microsoft Excel Hinweismeldung: Teile eines Arrays können nicht geändert werden.

Um eine Arrayformel zu bearbeiten oder zu löschen, muss der gesamte Arraybereich oder ein darüber hinausgehender Bereich zuvor markiert werden.

 

[1] Um Verwechslungen zwischen der linearen Algebra und den Excel-Matrixfunktionen zu vermeiden, wird im Folgenden lediglich der Begriff Arrayformel verwendet.

[2] Der gesamte Bereich einer Arrayformel kann ebenfalls markiert werden mit in der Menüleiste unter Bearbeiten / Gehe zu... (bzw. Tastenkombination Strg+G  bzw. Funktionstaste F5) / Inhalte... / Aktuelles Array aktivieren / OK. Hierzu muss mindestens eine Zelle des Arraybereichs zuvor markiert worden sein.

 

Haben Sie Fragen oder Anregungen zu diesem Artikel?

Dann senden Sie einfach eine Nachricht an:

E-Mail:

 

Lesen Sie auch:
___________________________________________________________________

Excel-Formel für den Variationskoeffizenten